home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
T-TPUG Old Monthly Disks
/
(c)tb.d64
/
1650 dial_load.c
(
.txt
)
next >
Wrap
Commodore BASIC
|
2007-02-04
|
1KB
|
53 lines
1 PRINT"[147]":FORI=1TO5:PRINT:NEXTI
2 PRINT" AUTODIAL.IMG PROLOGUE"
3 PRINT" BY JOHN FORKOSH -- 08/25/84"
4 PRINT
5 B1=56577:B2=56579:POKEB2,32:POKEB1,0
6 :
10 PRINT" 1) SET AUTOMODEM SWITCHES,"
11 PRINT" 2) PRESS ..."
12 PRINT" ... (O) ORIGINATE"
13 PRINT" ... (A) ANSWER"
14 PRINT" ... (X) LOAD FILE"
15 :
20 GETA$:IFA$=""THEN20
21 IFA$="A"THENPRINT:GOTO30
22 IFA$="O"THENPRINT:GOTO40
23 IFA$="X"THENPRINT:GOTO90
24 PRINT:GOTO11
25 :
30 PRINT" WAITING FOR RING ..."
31 B=PEEK(B1):B=BAND8:IFB<>0THEN31
32 PRINT" ... RING DETECTED"
33 GOTO90
34 :
40 INPUT" ENTER PHONE# ";A$
41 PRINT" DIALING ";
42 POKEB1,32:FORB=1TO1000:NEXTB
43 A=LEN(A$)
44 FORI=1TOA:I$=MID$(A$,I,1):PRINTI$;
45 N=VAL(I$):IFN=0THENN=10
46 GOSUB50:NEXTI:PRINT" COMPLETED"
47 GOTO90
48 :
50 FORI1=1TON:POKEB1,0:T=7
51 T=T-1:IFT>0THEN51
52 POKEB1,32:T=4
53 T=T-1:IFT>0THEN53
54 NEXTI1:T=70
55 T=T-1:IFT>0THEN55
56 RETURN
57 :
90 PRINT
91 PRINT" 3) ENTER NAME OF FILE"
92 PRINT" TO LOAD. (DON'T PRESS"
93 PRINT" RETURN UNTIL CARRIER"
94 INPUT" IS DETECTED.) ";F$
95 :
110 PRINT"[147]LOAD";CHR$(34);F$;CHR$(34);",8"
120 A$=CHR$(13)+"RUN"+CHR$(13)
130 FORI=1TOLEN(A$)
140 POKE630+I,ASC(MID$(A$,I)):NEXTI
150 POKE198,I-1
160 NEW